AXR$ .
B1        EQU      1
M         EQU      016
R0        EQU      0100
$(0) .
CONTTT*  DS    A0,SV
         S     A2,SV+2
         S     R2,SV+3
         SZ    A0
         ER    IALL$
          L,M       A0,0                . SET BACK TO THIRD WORD
          ER        PSR$
         L     A0,0,X11
         L     A2,0,A0
         SSL   A0,24
         S,S6  A0,MSG+6
         S     A2,TEMP
         L,S6  A0,MSG+5
         TE,U  A0,05
         J     EXIT
         SLJ   OCTAL
         S     A1,MSG+5
         L,H1  A2,TEMP
         SLJ   OCTAL
          S,S2      A1,MSG+4
          SSL       A1,6
          S,S1      A1,MSG+4
          SSL       A1,6
          S,S4      A1,MSG+2
          SSL       A1,6
          S,S3      A1,MSG+2
          SSL       A1,6
          S,S2      A1,MSG+1
          SSL       A1,6
          S,S1      A1,MSG+1
         L     A0,(0107,MSG)
         ER    PRINT$
          L,H1     A0,TEMP            CONTINGENCY CODES
          TNE,M    A0,024112          THAT'S MAX PAGES
          ER       ABORT$             KILL'EM DEAD
          TNE,M    A0,041712          MAX TIME
          ER       ABORT$
          ER    COND$
          AND   A0,(040,0)
          JZ    A1,EXIT
          AND       A0,(4,0)   . @SETC 4000 ALLOWS CONVERSATIONAL DUMP
          JNZ       A1,EXIT2    . @SETC 4400 RETURNS TO GET LIST
          J         SEXIT
EXIT     L,S3  A0,TEMP
         TNE,U A0,010
         J     SEXIT
EXIT2     DL        A0,SV
         L     A2,SV+2
         L     R2,SV+3
         J     1,X11
OCTAL*    J        $-$
         L,U   R2,5       . CONVERT RIGHT HALF OF
         SZ    A1         . A2 TO FIELD DATA IN A1
         DSC   A1,3
         SSL   A1,3
         JGD   R2,$-2
         A     A1,(0606060606060)
         J     *OCTAL
SV       RES   4
TEMP     +0
MSG      ' TYPE    CODE     CONT.    AD        PH-  '
.
.       THIS ROUTINE SAVES THE B, A, & R-REGISTERS FOR SUBSEQUENT
.       DUMPING.  ASSUMES R15 ALREADY SAVED, IN N0RGSA+43.
.
N0RGSV* J       $
        S       B1,N0RGSA+1
        S      R15,N0RGSA+43
        LX,M    B1,25
        LR      R15,2,B1
        SR      R15,N0RGSA+2,B1
        JGD     B1,$-2
        LX,M    B1,14
        LR      R15,R0,B1
        SR      R15,N0RGSA+28,B1
        JGD     B1,$-2
        L      R15,N0RGSA+43
        L      B1,N0RGSA+1
        J       *N0RGSV
.
N0RGRS*  J     $-$      RESTORE VOLATILE REGISTERS
       LX,M    B1,25
        L      R15,N0RGSA+2,B1
       S       R15,2,B1
       JGD     B1,$-2
        LX,M   B1,13
        LR     R15,N0RGSA+29,B1
        SR     R15,R1,B1
        JGD    B1,$-2
       L       B1,N0RGSA+1
       L       R15,N0RGSA+43
       J       *N0RGRS
N0RGSZ    INFO   2 3
$(3) .
N0RGSA*   RES       47                  . LEAVE SPACE FOR BSP PACKET
         END