.      NLST RECEIVES F50 NAME LIST ITEMS AND MAKES
        .       PROLOGUE ENTRIES IN PROL TABLE.
        .
          N5REG
$(1)
NLST*   .
NXITM     EQU       TT1                 . ALLOW SPACE FOR A COMPLETE NAMELIST
          L,M       AA1,NXITM+1
          S,H2      AA1,NLSTTB          . SAVE START OF TABLE
          L,S3      R5,ITEM             . NUMBER WITH THIS GROUP
NLRC      S         AA1,STP01
NLRA      JGD       R5,$+2
          J         NLRB
          LMJ       B11,FILE50
          J         *STP01
          L         AA2,STP01
          A,M       AA2,1
          S         AA2,STP01
          J         NLRA
NLRB      LMJ       B11,FILE50          GET NEXT STATEMENT TYPE
          +ITEMQ    . FLAG FOR READ AHEAD
          L,T1      AA2,ITEMQ
          TE,M      AA2,01251           . TEST FOR SUCCESSIVE NAMELIST
          J         NLRD
          L,S3      R5,ITEMQ            . NUMBER IN THIS GROUP
          JGD       R5,$+1
          LMJ       B11,FILE50          . READ NAME OF NAMELIST
          +NLRDX
          L,H2      AA2,NLRDX
          TE,H2     AA2,NXITM+1         . MAKE SURE ITS SAME NAMELIST
          J         NLRD
          SZ        NLRDX               . CLEAR FLAG OF WAITING TABLE
          J         NLRA                . CONTINUE READING REST OF TABLE
NLRD      L         AA1,STP01
          AN,H2     AA1,NLSTTB         . COMPUTE TOTAL NUMBER OF ITEMS
          S         AA1,R5
         SZ     VARCNT      COUNT DISCRETE VARIABLES
          LX,H2     BB1,NXITM+1         . SYM(N1)  . NAMELIST NAME
          L,H1      A1,2,BB1
          AND,M     A1,0770
          SZ,H1     NLSTTB              . FLAG TO SKIP UNREFERENCED NAMELIST
          TNE,M     A2,0570
          S,H1      A2,NLSTTB
        JGD     R5,$+1                  . MINUS 1
        JGD     R5,$+2
        J       NLST6
        L,H1   AA3,CRGSYM
        L,H2   AA4,CRGSYM
        SX      BB3,SAVE
        SX      BB4,SAVE+1
        LX      BB3,(1,2)               . ITEM TABLE INDEX
NLST1   SZ      NLITM+1
          TZ,H1     NLSTTB
          J         NLST2B              . SKIP UNREFERENCED NAMELIST
          L         AA1,NXITM,BB3       . SYM(ARG)
        SA,H1   AA1,NLITM
        SZ     FLMP     NON ZERO FOR GLOBAL DUMMY
        TNW,H1 AA3,NLITM      TEST FOR GLOBAL DUMMY
        S      AA3,FLMP
          LA,S3     AA2,NXITM,BB3       . DOT
          LA,T1     AA1,NXITM,*BB3
        TNE,M   AA2,3
        J       NLST7       DOT=3
        S      AA1,VARCNT
        SSC     AA1,35      CALCULATE NL TABLE 1 OFFSET
        AA,T3    AA1,2,BB1
      AA,M      AA1,2       2*TOF+N+2  FOR DOT=1
        TNE,M   AA2,2
        AA,M    AA1,1       2*TOF+N+3  FOR DOT=2
        SA,H2   AA1,NLITM        OFFSET
        SX,H2   BB1,NLITM+1      L=SYM(N1)
NLST2   SA,S3   AA2,NLITM+1       F CODE
        LA      AA1,NLITM
        L      BB2,PROLX
        TZ     FLMP
        L      BB2,PROLXM     GLOBAL VARIABLES ARE STORED BACKWARDS
        SA      AA1,PROL,BB2
        LA      AA1,NLITM+1
        SA     AA1,PROL+1,BB2
        TZ     FLMP
        J      NLST2A
        AX,M   BB2,2
        S      BB2,PROLX
NLST2B  JGD    R5,NLST1
NLST6   LX      BB3,SAVE
        LX      BB4,SAVE+1
          TNZ       NLRDX
        J       PHS5G
          L,S3      R5,ITEMQ
          JGD       R5,$+1
          L         AA1,NLRDX
          SZ        NLRDX
          S         AA1,NXITM+1
          L,M       AA1,NXITM+2
.         S,H2      AA1,NLSTTB          . SAVE START OF TABLE
          J         NLRC
NLST2A  AN,M   BB2,2
        S      BB2,PROLXM     GLOBAL DUMMIES ARE STORED BACKWARDS
        J      NLST2B
NLST7     LA,T1     AA1,NXITM-1,BB3     . TOF
          LX,H1     BB4,NXITM+1         . SYM (VL)
        L      BB4,0,BB4
        DSL     AA1,1
          AN       BB4,VARCNT
        AA,M    AA1,1         TOF/2+1
        SA,H2   AA1,NLITM
        LA,M    AA1,1        FOR D=1
        TP      AA2
        SA,S1   AA1,NLITM+1
        LA      AA1,0,BB4       SYM(HOL)
        SA,H2    AA1,NLITM+1          TO L
        LA,M    AA2,3
        J       NLST2
$(2)
VARCNT  +0
SAVE    RES     2
NLITM   RES     2
FLMP    +0    .     NON ZERO FOR GLOBAL DUMMYS                          REENT
NLRDX     +0
NLSTTB    +0
        END